home *** CD-ROM | disk | FTP | other *** search
/ Aminet 44 / Aminet 44 (2001)(GTI - Schatztruhe)[!][Aug 2001].iso / Aminet / demo / sound / UP-7-001.lha / ep-install / Start < prev    next >
AmigaDOS Script File  |  1980-01-11  |  2KB  |  80 lines
  1. .KEY PREFSWIN/s,MUI/s,HELP/s
  2.  
  3. ; $VER: UPRoughEP Start-script 1.0 (09-Jul-00) ©2000 Up Rough Soundsystem
  4.  
  5. ;Just if boot without startup-sequence...
  6. C:Assign >NIL: ENV: EXISTS              
  7. IF WARN
  8.     IF NOT EXISTS "Ram:Env"
  9.         C:MakeDir >NIL: Ram:Env
  10.         C:MakeDir >NIL: Ram:Env/sys
  11.     ENDIF
  12.     C:Assign >NIL: ENV: Ram:Env
  13. ENDIF
  14.  
  15. C:Assign >NIL: T: EXISTS
  16. IF WARN
  17.     IF NOT EXISTS "Ram:T"
  18.         C:MakeDir >NIL: Ram:T
  19.     ENDIF
  20.     C:Assign >NIL: T: Ram:T
  21. ENDIF
  22.  
  23. ;Help argument
  24. IF "<HELP>" EQ "HELP"
  25.     Set Choice `RequestChoice "EP help message!" "EPStart is a script that makes it easier to start EP.*NU SHOULD use it instead of starting EP directly :)*NThe arguments u can pass to it r:*NHELP  -  Show this requester...*NPREFSWIN  -  Open the prefs window.*NMUI  -  Use mui for the prefs window." "Start me up!" "Quit"`
  26.     IF VAL $Choice EQ 0
  27.         Skip OUCH
  28.     ENDIF
  29. ENDIF
  30.  
  31. ;Fix the assign if it doesn't exist...
  32. C:Assign >NIL: EP: EXISTS
  33. IF WARN
  34.     IF EXISTS "EP"                  ;Started from upep dir?
  35.         C:Assign >NIL: EP: ""       ;Yepps
  36.     ELSE
  37.         Set Choice `RequestChoice "EP error message!" "EP: hasn't been assigned and couldn't be assigned*Nbecause u didn't start this script from the dir u've*Ngot the EP exe in...what to do now...?" "Assign req" "Quit"`
  38.         IF VAL $Choice EQ 0     ;Quit?
  39.             Skip OUCH
  40.         ELSE                    ;Assign requester
  41.             UnSet UPEPDir
  42.             Set UPEPDir `RequestFile TITLE "Select path for EP:" DRAWERSONLY`
  43.             IF "$UPEPDir" EQ "*$UPEPDir"
  44.                 Skip OUCH       ;Cancel
  45.             ELSE
  46.                 IF "$UPEPDir" EQ ""             
  47.                     C:Assign >NIL: EP: ""           ;OK was just pressed
  48.                 ELSE
  49.                     C:Assign >NIL: EP: "$UPEPDir"   ;A dir was selected
  50.                 ENDIF
  51.             ENDIF
  52.         ENDIF
  53.     ENDIF
  54. ENDIF
  55.  
  56. ;Run the exe...
  57. Set OldDir `C:Cd`   ;Save current dir
  58. C:Cd >NIL: "EP:"
  59.  
  60. Set UPEPCom "EP"    ;Exename
  61.  
  62. IF "<PREFSWIN>" EQ "PREFSWIN"       ;PREFSWIN arg
  63.     Set UPEPCom "$UPEPCom PREFSWIN"
  64. ENDIF
  65.  
  66. IF "<MUI>" EQ "MUI"                 ;MUI arg
  67.     stack 10000                     ;U never know with mui proggies...
  68.     Set UPEPCom "$UPEPCom MUI"
  69. ENDIF
  70.  
  71. $UPEPCom                ;Run
  72.  
  73. C:Cd >NIL: "$OldDir"    ;Restore dir
  74.  
  75. Quit                    ;Exit
  76.  
  77. Lab OUCH
  78. C:RequestChoice >NIL: "EP sad message :(" "OUCH! That hurts...." "I'll try again later :)"
  79. Quit
  80.